0
\$\begingroup\$

I am simulating circuit which uses NPN IRFZ44N power MOSFET and MBR1560CT rectifier (used in the circuit just as a shottky diode, connecting 2 out of its 3 legs only).

Here is a circuit made in “EveryCircuit”: enter image description here This simulation application asks for parameters I can not identify:

1. For NPN MOSFET:

  • Width
  • Length
  • KP
  • VTO
  • Lambda

2. For Schottky diode:

  • Breakdown voltage
  • Saturation current
  • Ohmic resistance
  • Emission coefficient
  • Junction capacitance

Could you help me find or connect those parameters with values from the datasheet?

EDIT: I found this page: http://www.eecg.toronto.edu/~kphang/teaching/spice/part3.html#7.5 which explains a lot yet it is very concise. It this the best / official reference?

Improve this question
\$\endgroup\$
4
  • 3
    \$\begingroup\$ Brief answer: on the manufacturer website, search for the part you are interested in. From the part page you can sometimes get a device model that can be used with pspice. Download the model, it is a text file. In the text file there are all the parameters you need. Identifying them is not very easy for a beginner, but the model file is where you wanna start from. \$\endgroup\$ – Vladimir Cravero May 15 '16 at 0:02
  • \$\begingroup\$ I managed to find KVO, KP and Lambda for MOSFET. I still can not find values for Lenght and Width. I see they affect simulation once i play with them, so it seems they are not just physical dimensions. DO you know what they are? \$\endgroup\$ – Lukasz May 15 '16 at 0:17
  • 3
    \$\begingroup\$ They actually are physical dimensions, they reffer to the physical size of the actual active part of the silicon, more area means more current handling and lower resistance, skinnier areas (with the same area) can sometimes have faster switching if the gate is driven on the long axis. Unfortunately, most all modern fets have quite complex geometries in order to get maximum performance (like stripfets which are kinda like several long skinny fets in parallel or hexfets which are like a checkerboard of gate and source connections). Most manufacturers publish spice models for their parts anyway. \$\endgroup\$ – Sam May 15 '16 at 0:51
  • 1
    \$\begingroup\$ This circuit may be experimental, but in a real-world situation the mosfet would be a P-channel. The reason why is that if your input pulses stop, the N-channel mosfet will always be on. Your pulses are turning the N-channel off for 500uS, with a P-channel mosfet it would turn ON for 500uS. Just an observation. \$\endgroup\$ – user105652 May 15 '16 at 2:14
1
\$\begingroup\$

To the original question, it is rare to see all the necessary parameters for a device in the data sheet, particularly transistors. Some diode manufacturers do put all the necessary parameters in the datasheet.

The model file is here for the MOSFET (and it includes all the necessary parameters).

Just in case the link goes stale, here is the model:

There is a list of MOSFET parameters here as used in SPICE.

    .SUBCKT irfz44n 1 2 3
**************************************
*      Model Generated by MODPEX     *
*Copyright(c) Symmetry Design Systems*
*         All Rights Reserved        *
*    UNPUBLISHED LICENSED SOFTWARE   *
*   Contains Proprietary Information *
*      Which is The Property of      *
*     SYMMETRY OR ITS LICENSORS      *
*Commercial Use or Resale Restricted *
*   by Symmetry License Agreement    *
**************************************
* Model generated on Apr 24, 96
* Model format: SPICE3
* Symmetry POWER MOS Model (Version 1.0)
* External Node Designations
* Node 1 -> Drain
* Node 2 -> Gate
* Node 3 -> Source
M1 9 7 8 8 MM L=100u W=100u
* Default values used in MM:
* The voltage-dependent capacitances are
* not included. Other default values are:
*   RS=0 RD=0 LD=0 CBD=0 CBS=0 CGBO=0
.MODEL MM NMOS LEVEL=1 IS=1e-32
+VTO=3.56214 LAMBDA=0 KP=39.3974
+CGSO=1.25255e-05 CGDO=2.2826e-07
RS 8 3 0.0133305
D1 3 1 MD
.MODEL MD D IS=9.64635e-13 RS=0.00967689 N=1.01377 BV=55
+IBV=0.00025 EG=1.08658 XTI=2.9994 TT=1e-07
+CJO=1.39353e-09 VJ=0.5 M=0.42532 FC=0.5
RDS 3 1 2.2e+06
RD 9 1 0.0001
RG 2 7 2.20235
D2 4 5 MD1
* Default values used in MD1:
*   RS=0 EG=1.11 XTI=3.0 TT=0
*   BV=infinite IBV=1mA
.MODEL MD1 D IS=1e-32 N=50
+CJO=1.52875e-09 VJ=0.5 M=0.584414 FC=1e-08
D3 0 5 MD2
* Default values used in MD2:
*   EG=1.11 XTI=3.0 TT=0 CJO=0
*   BV=infinite IBV=1mA
.MODEL MD2 D IS=1e-10 N=0.408752 RS=3e-06
RL 5 10 1
FI2 7 9 VFI2 -1
VFI2 4 0 0
EV16 10 0 9 7 1
CAP 11 10 2.06741e-09
FI1 7 9 VFI1 -1
VFI1 11 6 0
RCAP 6 10 1
D4 0 6 MD3
* Default values used in MD3:
*   EG=1.11 XTI=3.0 TT=0 CJO=0
*   RS=0 BV=infinite IBV=1mA
.MODEL MD3 D IS=1e-10 N=0.408752
.ENDS

The schottky model is here, and again, in case the link goes stale:

*SRC=MBR1560CT;DI_MBR1560CT;Diodes;Si;  60.0V  15.0A  5.00ns   Diodes Inc. Schottky - One element of device
.MODEL DI_MBR1560CT D  ( IS=11.3u RS=2.64m BV=60.0 IBV=25.0u
+ CJO=530p  M=0.333 N=1.87 TT=7.20n )
Improve this answer
\$\endgroup\$
1
  • \$\begingroup\$ In the MOSFET sheet: does L=100u stand for length and W=100u for width? \$\endgroup\$ – Lukasz May 15 '16 at 10:16

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.