0
\$\begingroup\$

Hello to everyone and apologies if this question has been asked before, but I am searching more than an hour every time before I post.

I want to simulate the LM13700 Operational Transconductance Amplifier in PSpice. I downloaded the specific spice model from Texas Instruments. This is not the first time I implement a spice model to PSpice, so it is 100% done right.

The problem is the pin setup. The Spice model is one such Operational Amplifier and not two, as the model taken from the official datasheet.

More specifically, the spice model has 9 pins named (watch carefully the numbers close to the end) "1,2,3,4,5,6,7,8,11" without 9 or 10. There is no specification as to which pin is which in the datasheet.

The model in the datasheet, on the other hand, has 16 pins and it is specific as to which is which.

Is there any way to know what the pins do exactly just by looking in the spice model code? Thank you in advance.

Here is the complete spice model code:

.SUBCKT LM13700/NS  1 2 3 4 5 6 7 8 11
*
* Features:
* gm adjustable over 6 decades.
* Excellent gm linearity.
* Linearizing diodes.
* Wide supply range of +/-2V to +/-22V.
*
* Note:  This model is single-pole in nature and over-estimates
*       AC bandwidth and phase margin (stability) by over 2X. 
*       Although refinement may be possible in the future, please
*       use benchtesting to finalize AC circuit design.
* 
* Note: Model is for single device only and simulated
*       supply current is 1/2 of total device current.
*
******************************************************
* 
C1  6  4  4.8P
C2  3  6  4.8P
* Output capacitor  
C3  5  6  6.26P                                       
D1  2  4  DX
D2  2  3  DX
D3  11 21 DX
D4  21 22 DX
D5  1  26 DX
D6  26 27 DX
D7  5  29 DX
D8  28 5  DX
D10 31 25 DX
* Clamp for -CMR  
D11 28 25 DX                                        
* Ios source 
*    
F1  4  3  POLY(1)   V6 1E-10 5.129E-2 -1.189E4 1.123E9 
F2  11 5  V2        1.022
F3  25 6  V3        1.0
F4  5  6  V1        1.022
* Output impedance 
F5  5  0  POLY(2)   V3 V7 0 0 0 0 1                  
G1  0  33 5         0 .55E-3
I1  11 6  300U
Q1  24 32 31        QX1
Q2  23 3  31        QX2
Q3  11 7  30        QZ
Q4  11 30 8         QY
V1  22 24 0V
V2  22 23 0V
V3  27 6  0V
V4  11 29 1.4
V5  28 6  1.2
V6  4  32 0V
V7  33 0  0V
.MODEL QX1 NPN (IS=5E-16     BF=200 NE=1.15 ISE=.63E-16 IKF=1E-2)
.MODEL QX2 NPN (IS=5.125E-16 BF=200 NE=1.15 ISE=.63E-16 IKF=1E-2)
.MODEL QY  NPN (IS=6E-15     BF=50)
.MODEL QZ  NPN (IS=5E-16     BF=266)  
.MODEL DX  D   (IS=5E-16)
.ENDS
\$\endgroup\$

2 Answers 2

3
\$\begingroup\$

This does not look like the same model I got from TI website.

Here is the header:

*//////////////////////////////////////////////////////////////////////
* (C) National Semiconductor, Inc.
* Models developed and under copyright by:
* National Semiconductor, Inc.  

*/////////////////////////////////////////////////////////////////////
* Legal Notice: This material is intended for free software support.
* The file may be copied, and distributed; however, reselling the 
*  material is illegal

*////////////////////////////////////////////////////////////////////
* For ordering or technical information on these models, contact:
* National Semiconductor's Customer Response Center
*                 7:00 A.M.--7:00 P.M.  U.S. Central Time
*                                (800) 272-9959
* For Applications support, contact the Internet address:
*  [email protected]

* \\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\            
* LM13700 Dual Operational Transconductance Amplifier                 
* \\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\                 
*
*                   Amplifier Bias Input
*                   | Diode Bias
*                   | | Positive Input
*                   | | | Negative Input
*                   | | | | Output
*                   | | | | | Negative power supply
*                   | | | | | | Buffer Input
*                   | | | | | | | Buffer Output
*                   | | | | | | | | Positive power supply
*                   | | | | | | | | |
.SUBCKT LM13700/NS  1 2 3 4 5 6 7 8 11
* snip

I've got the feeling you got the mod file from some second hand source, like a supplier. This is not intrinsically bad, but always check the manufacturer's website.

Another possibility is that your spice simulator strips the 'unnecessary' lines of a mod file after you import it, where unnecessary might mean 'everything that comes before the .SUBCKT statement. This strucks me as quite odd and almost always unwanted behavior, but it seems that it is precisely what did happen here.

The "pipes 'n spaces" notation is widely used in .mod files, I checked on TI website exactly because your file seemed to miss something.

\$\endgroup\$
6
  • \$\begingroup\$ Good work dude. \$\endgroup\$
    – Andy aka
    Jul 14, 2016 at 17:31
  • \$\begingroup\$ Wow, so much love! Really, I am just home sick and got too much time on my hands. I figured I'd try and go for the 10k rep gaining unlimited powah. \$\endgroup\$ Jul 14, 2016 at 19:00
  • \$\begingroup\$ May the force be with you! \$\endgroup\$
    – Andy aka
    Jul 14, 2016 at 20:28
  • \$\begingroup\$ Upvoted for 10k \$\endgroup\$
    – Daniel
    Jul 14, 2016 at 21:36
  • \$\begingroup\$ Oh one more thing, sir Vladimir Cravero. The code that you saw is from the official Texas Instruments site: ti.com/product/LM13700 Should I find it from somewhere else? \$\endgroup\$ Jul 15, 2016 at 10:58
0
\$\begingroup\$

I understand what is confusing you Manolis. There is 11 pins instead of 16 in the TI model because the model is only for 1 OTA and not two like the actual IC chip has.

If you look at the pinout of the .Mod file you will see there is only one set of inputs, unlike in the real chips pinout.

enter image description here

enter image description here

\$\endgroup\$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.