Sending data over UART when data has been received over I2C on AVR

Question

So I'm receiving data from an ESP module via I2C. I then need to send this data immediately over the UART. Not sure how I should do this. Would it be ok to place the UART sending inside the i2c receive interrupt?

Answer 1

Are you using the Arduino IDE to program your ESP8266? Never put Serial code into an interrupt function. More info here. Check the section Hints for writing ISRs

Regardless of the IDE you're using, I'd recommend you to define a global variable in your code (generally a boolean) to inform that your data was received over the I2C protocol, then in the main part of the code (loop function in Arduino programs) you could check this variable and then send the received data over the UART.

Here is an example using the Arduino IDE. Of course, you'll have to use the correspondent Wire library to your ESP8266.

EDIT: Added the concept of atomicity to ensure our variable inputString is not messed up with consecutive unhandled interruption. For more details, you can check this demonstration

#include <Wire.h>
#include <util/atomic.h>

String inputString = ""; // a String to hold incoming data
volatile bool stringCompleted = false; // whether the string is complete

void setup() {
  Wire.begin(0x20); // join i2c bus with address 0x20
  Wire.onReceive(receiveEvent); // register event

  // reserve 200 bytes for the inputString:
  inputString.reserve(200);

  Serial.begin(9600); // start serial for output
}

void loop() {
  ATOMIC_BLOCK(ATOMIC_RESTORESTATE) {
    // print the string when a newline arrives:
    if(stringCompleted) {
      Serial.println(inputString);
      // clear the string:
      inputString = "";
      stringCompleted = false;
    }
  }
}

// function that executes whenever data is received from master
// this function is registered as an event, see setup()
void receiveEvent(int howMany) {
  while (Wire.available() > 0) { // loop through all
    char inChar = (char)Wire.read(); // receive byte as a character

    inputString += inChar; // add it to the inputString:

    // if the incoming character is a newline, set a flag so the main loop can
    // do something about it:
    if(inChar == '\n') {
      stringCompleted = true;
    }
  }
}