How to set forward voltage for a diode model in NGSpice?

Question

I am trying to understand the documentation for the diode model, but I could not find how to set the forward voltage value.

Can someone help me simulate silicon diode that has a forward voltage of approximately 0.7 volts?

Answer 1

You do not simply "set" the forward voltage. The forward voltage is determined by a combination of model parameters. Here's a model I found for the 1N4148 which is a commonly used Silicon diode:

******************************************
*1N4148
*VRRM = 100V
*IFRM = 450 mA 
*trr  = 4ns
*
*Package: SOD 27
*
*Package Pin 1 : Cathode
*Package Pin 2 : Anode
*
*Simulator: PSPICE
*
******************************************
*
.SUBCKT 1N4148 1 2 
*
* The resistor R1 does not reflect 
* a physical device. Instead it
* improves modeling in the reverse 
* mode of operation.
*
R1 1 2 5.827E+9 
D1 1 2 1N4148
*
.MODEL 1N4148 D 
+ IS = 4.352E-9 
+ N = 1.906 
+ BV = 110 
+ IBV = 0.0001 
+ RS = 0.6458 
+ CJO = 7.048E-13 
+ VJ = 0.869 
+ M = 0.03 
+ FC = 0.5 
+ TT = 3.48E-9 
.ENDS

If you use these parameters with the standard PSPICE diode model you should get (I did not check it for you, so no guarantees) a diode with a forward voltage of around 0.7 V at "normal" forward operation (a couple of mA of current flowing).

Answer 2

Chapter 7 of the NGSpice Manual defines all the diode parameters , but these are often not found in datasheets.

As a general rule Vf for a diode is given at a low current where the bulk resistance begins to dominate the forward voltage which implies a linear V/I response above this current level and you know it has a logarithmic response at low currents.

Si diode log curve

I have discovered that the bulk resistance is related to the size and power rating of the diode such that Rs=0.5~1/Pmax which is good for estimating within 50%. The best diodes are towards 0.25/Pmax=Rs and this also applies to LED’s, Zener’s and BJT’s to reasonably good correlation. The poorer diodes or older technology would be Rs>1/Pmax. The Pmax is the 85’C steady max power rating, not the actual power dissipated.

Concluding Remarks

0.6V @ 1mA @ 30’C applies to most Si diodes since it is low power and little or no self heating.

For all Si diodes, 0.7V may be at >> 1mA and not a good reference for small signal , low-current diodes rated for high speed.

This has a much wider current tolerance as Rs (Bulk resistance) , power dissipation , NTC (Vf vs T) and other diode factors come to play near and above 0.7V. Thus the datasheets for all packages of 1N4148 depend on stated assumptions of Cu area heatsink, ambient T ...

but have Vf (MAX) @ If specs ranging from ...

• 1.25V @ 150mA
• 1.2V @ 100mA
• 1V @ 100mA
• 1V @ 50mA
• 1V@ 10mA
• 0.855V @ 10mA

Datasheets