I have to design a phase angle dimmer using a triac. For this, I have read How do I drive a TRIAC from a microcontroller (for low voltages)?

This forum really turns out to give me a good solution .. but before that, I want to simulate this circuit in LTspice or multisim or any software ..

I have googled for the spice model of MOC3022M but have not succeeded .. Can anyone give me a suggestion?

  • 2
    \$\begingroup\$ You can model the optoisolator as a diode on the transmit side and a CCCS controlled by the diode current and driving the base of a BJT on the receive side. Getting the parameters right will require carefully reading the datasheet though. You'll especially need to tweak the diode part to behave like an LED and not like a standard silicon diode. \$\endgroup\$ – The Photon Nov 1 '12 at 23:00

A great place to find SPICE models for LTSpice is the Yahoo LTSpice Group. You will need to create a Yahoo account to join the group (it is free). After that you will have a huge selection of part models and tutorials to help you with SPICE simulations in LTSpice.

I even found a model for the MOC3022M on the site:

* Helmut Sennewald  8/10/2004
* MOC3022   I_trig=5mA
*  D+  D-  MT2  MT1
.SUBCKT MOC3022 1 2 3 4
.PARAM Itrig=5m
.PARAM RH1=20k
.PARAM RH2=20k
.PARAM RH3=16.7k
Q2 vb1 vb1p vd1 0 PNP1
Q1 vb1p vb1 4 0 NPN1
R3 vb1 4 {RH2}
D1 1 2 DL
R1 ctrl1 4 1
C1 ctrl1 4 10µ
R2 ctrl1 vb1 {RH1}
R4 vd1 vb1p {RH3}
B1 ctrl1 4 I=-500*I(D1)*3m/Itrig 
R6 vd2 vb2 {RH2}
D3 vd2 3 D1
Q3 vb2 vb2p 4 0 PNP1
Q4 vb2p vb2 vd2 0 NPN1
E1 vd2 N001 ctrl1 4 -1
R5 N001 vb2 {RH1}
R7 vb2p 4 {RH3}
D2 3 vd1 D1
R34 3 4 100MEG
.MODEL PNP1 PNP(Is=1e-15 BF=10 Cjc=10p Cje=20p Tf=0.1u Ise=1e-12)
.MODEL NPN1 NPN(Is=1e-15 BF=10 Cjc=10p Cje=20p Tf=0.1u Ise=1e-12)
.MODEL D1 D(Is=0.1u Rs=2 Cj0=50p)
.MODEL DL D(Is=1e-20 Rs=5)

Remember it is just model, so you may want to perform some tests around your operating point and compare the models performance with the datasheet.


Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.