2
\$\begingroup\$

TL;DR : I want to use a darlington transistor model(BD679&BD680) within LTspice. Can I do that by using default symbols npn or pnp from component selector menu?

I have done it with TIP41C & TIP42C, the downloaded file for them were like this:

******
* Spice Model
* Item: TIP41C
* Date: 8/11/10
* Revision History: A
* ==========================================================
* This model was developed by: 
* Central Semiconductor Corp.
* 145 Adams Avenue
* Hauppauge, NY 11788
*
* These models are subject to change without notice.
* Users may not directly or indirectly re-sell or 
* re-distribute this model. This model may not 
* be modified, or altered without the consent of Central Semiconductor Corp. 
*
* For more information on this model contact
* Central Semiconductor Corp. at:
* (631) 435-1110 or Engineering@centralsemi.com
* http://www.centralsemi.com
* ==========================================================
******
*SRC=TIP41C;TIP41C;BJTs NPN; Si;100.0V  3.00A  3MHz   Central Semi Central Semi

.MODEL TIP41C  NPN (
+ IS=290.83E-15
+ BF=113.55
+ VAF=100
+ IKF=1.9905
+ ISE=1.3946E-12
+ NE=1.4763
+ BR=.1001
+ VAR=100
+ IKR=10.010E-3
+ ISC=320.65E-12
+ NC=1.8994
+ NK=.58929
+ RB=.71129
+ CJE=348.44E-12
+ VJE=.78228
+ MJE=.42865
+ CJC=184.26E-12
+ VJC=.47897
+ MJC=.40458
+ TF=36.381E-9
+ XTF=100.32
+ VTF=21.563
+ ITF=28.791
+ TR=10.000E-9 )

I have just copied and added .MODEL part to the end of standard.bjt file. And I was able to choose it from "pick new transistor" menu. So, I now downloaded the library file for BD680 darlington transistor but it is more complicated than the former TIP41C case.

**************************************
*      Model Generated by MODPEX     *
*Copyright(c) Symmetry Design Systems*
*         All Rights Reserved        *
*    UNPUBLISHED LICENSED SOFTWARE   *
*   Contains Proprietary Information *
*      Which is The Property of      *
*     SYMMETRY OR ITS LICENSORS      *
*    Modeling services provided by   *
* Interface Technologies www.i-t.com *
**************************************
.SUBCKT bd680 1 2 3
* Model generated on Feb 14, 2004
* Model format: PSpice
* Darlington macro model
* External node designations
* Node 1 -> Collect
* Node 2 -> Base
* Node 3 -> Emitter
Q1 1 2 4 qmodel
Q2 1 4 3 q1model 2.46191
D1 1 3 dmodel
R1 2 4 8000
R2 4 3 120
* Default values used in dmodel
*   EG=1.11 TT=0 BV=infinite
.MODEL dmodel d
+IS=1e-12 RS=10 N=1 XTI=3
+CJO=0 VJ=0.75 M=0.33 FC=0.5
.MODEL qmodel pnp
+IS=2.23835e-12 BF=149.682 NF=1.2 VAF=59.0895
+IKF=0.118079 ISE=9.09119e-14 NE=1.42175 BR=0.587475
+NR=0.75 VAR=100.388 IKR=0.0934405 ISC=9.09118e-14
+NC=2 RB=15.5445 IRB=0.450416 RBM=12.8364
+RE=0.0939759 RC=2.76027 XTB=0.497353 XTI=2.9942 EG=1.05
+CJE=1e-11 VJE=0.75 MJE=0.33 TF=1e-09
+XTF=1 VTF=10 ITF=0.01 CJC=1e-11
+VJC=0.75 MJC=0.33 XCJC=0.9 FC=0.5
+TR=1e-07 PTF=0 KF=0 AF=1
.MODEL q1model pnp
+IS=2.23835e-12 BF=149.682 NF=1.2 VAF=59.0895
+IKF=0.118079 ISE=9.09119e-14 NE=1.42175 BR=0.587475
+NR=0.75 VAR=100.388 IKR=0.0934405 ISC=9.09118e-14
+NC=2 RB=15.5445 IRB=0.450416 RBM=12.8364
+RE=0.0939759 RC=2.76027 XTB=0.497353 XTI=2.9942 EG=1.05
+CJE=1e-11 VJE=0.75 MJE=0.33 TF=1e-09
+XTF=1 VTF=10 ITF=0.01 CJC=0
+VJC=0.75 MJC=0.33 XCJC=0.9 FC=0.5
+TR=1e-07 PTF=0 KF=0 AF=1
.ENDS

So I assume I cannot just copy this into standart.bjt file.

When I was also trying to use LM741, I added its library file in form of .sub file to the /sub folder of LTspice and I was able to use .lib LM741.sub. I have been choosing opamp2 from component selector menu and just renaming its name to LM741 was sufficient. But this method did not work for BD680 darlington. I assume opamp2 for intended to be used with sub models however pnp is not. But I am not sure.

So what can I do?

update: I think dragging the library file into LTspice and creating a new symbol can be one of the solutions. I have just figured it out. So, you can provide better solutions if you have any.

\$\endgroup\$
1
\$\begingroup\$

So I assume I cannot just copy this into standart.bjt file.

You can copy one line models that are based off of the npn or pnp spice model such as this:

.model kt3102e npn bf=5000 br=5 is=.2p tf=.4n cjc=12p cje=12p vaf=100 tr=45n rc=.5 rb=1.5k rbm=80 irb=10u ikf=50m xcjc=0.3 kf=5f eg=1.11 ne=1.35 ise=0.1p nc=2 isc=1p Vceo=20 Icrating=100m mfg=USSR

so you could copy this into the bjt file (but that isn't legal without obtaining permission):

.MODEL TIP41C  NPN (  IS=290.83E-15 BF=113.55 VAF=100 IKF=1.9905 ISE=1.3946E-12 NE=1.4763 BR=.1001 VAR=100 IKR=10.010E-3 ISC=320.65E-12

+ NC=1.8994 NK=.58929 RB=.71129 CJE=348.44E-12 VJE=.78228 MJE=.42865 CJC=184.26E-12 VJC=.47897 MJC=.40458 TF=36.381E-9 XTF=100.32 VTF=21.563 ITF=28.791 TR=10.000E-9 )

So the tIP41C works in the .bjt file, but sub-circuit files don't work (files with more than one spice line as far as I'm aware) so the bd680 won't work in the .bjt file.

Either file can be imported by using the include statement:

.include C:\Whatever path\LTspiceXVII\SQ7414ENb_PS.lib

Then finding an existing model (this works for any model) and pressing alt and clicking, you should get a menu like this. Change the type prefix to X and the spice line to the model in the include file

enter image description here

More complete description on this here: http://ltwiki.org/LTspiceHelpXVII/LTspiceHelp/html/Third_party_Model.htm

|improve this answer|||||
\$\endgroup\$
  • \$\begingroup\$ Well thanks, but which symbol can I use for darlington pair? \$\endgroup\$ – muyustan Dec 11 '19 at 19:29
  • 1
    \$\begingroup\$ Regular NPN or PNP \$\endgroup\$ – Voltage Spike Dec 11 '19 at 20:03
  • \$\begingroup\$ @muyustan To be fair, anything that has three pins (or however many pins the subcircuit has), be they in LTspice's own library, or made elsewhere. But the builtin NPN/PNP would look more the part. \$\endgroup\$ – a concerned citizen Dec 12 '19 at 17:32

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.