How to create a VHDL function/procedure that can return true or false based on value of signals outside it?

Question

Here is the function I am trying to write:

procedure ASCERTAIN_CALL_VALIDITY is
begin
  (SESSION_CHECK_ACTIVATION_MSG_IN and ACTIVATION_MSG_RECEIVED_INT) or
  (SESSION_CHECK_ACTIVATION_ACKNOWLEDGE_MSG_IN and ACTIVATION_ACKNOWLEDGE_MSG_RECEIVED_INT) or
  (SESSION_CHECK_START_SESSION_MSG_IN and START_SESSION_MSG_RECEIVED_INT) or
  (SESSION_CHECK_STARTUP_CONFIGURATION_MSG_IN and STARTUP_CONFIGURATION_MSG_RECEIVED_INT) or
  (SESSION_CHECK_TURN_OFF_MSG_IN and TURN_OFF_MSG_RECEIVED_INT)
end procedure;

I want to return the value from logic processing and store inside a signal or variable outside it. Now the problem is that, functions can't access signals outside of them. Procedures can't return a value. So what do I do now?

Answer 1

Either return a value from the procedure call (which is a statement) or use an impure function:

entity q231 is
end entity;

architecture foo of q231 is
    signal SESSION_CHECK_ACTIVATION_MSG_IN: boolean;
    signal ACTIVATION_MSG_RECEIVED_INT: boolean;
    signal SESSION_CHECK_ACTIVATION_ACKNOWLEDGE_MSG_IN: boolean;
    signal ACTIVATION_ACKNOWLEDGE_MSG_RECEIVED_INT: boolean;
    signal SESSION_CHECK_START_SESSION_MSG_IN: boolean;
    signal START_SESSION_MSG_RECEIVED_INT: boolean;
    signal SESSION_CHECK_STARTUP_CONFIGURATION_MSG_IN: boolean;
    signal STARTUP_CONFIGURATION_MSG_RECEIVED_INT: boolean;
    signal SESSION_CHECK_TURN_OFF_MSG_IN: boolean;
    signal TURN_OFF_MSG_RECEIVED_INT: boolean;
    
    procedure ASCERTAIN_CALL_VALIDITY (result: out boolean) is  -- ADDED out parameter
    begin
        result :=   -- ADDED
      (SESSION_CHECK_ACTIVATION_MSG_IN and ACTIVATION_MSG_RECEIVED_INT) or
      (SESSION_CHECK_ACTIVATION_ACKNOWLEDGE_MSG_IN and ACTIVATION_ACKNOWLEDGE_MSG_RECEIVED_INT) or
      (SESSION_CHECK_START_SESSION_MSG_IN and START_SESSION_MSG_RECEIVED_INT) or
      (SESSION_CHECK_STARTUP_CONFIGURATION_MSG_IN and STARTUP_CONFIGURATION_MSG_RECEIVED_INT) or
      (SESSION_CHECK_TURN_OFF_MSG_IN and TURN_OFF_MSG_RECEIVED_INT) ; -- ADDED ;
    end procedure;
    
    impure function call_validity return boolean is
    begin
        return (SESSION_CHECK_ACTIVATION_MSG_IN and ACTIVATION_MSG_RECEIVED_INT) or
      (SESSION_CHECK_ACTIVATION_ACKNOWLEDGE_MSG_IN and ACTIVATION_ACKNOWLEDGE_MSG_RECEIVED_INT) or
      (SESSION_CHECK_START_SESSION_MSG_IN and START_SESSION_MSG_RECEIVED_INT) or
      (SESSION_CHECK_STARTUP_CONFIGURATION_MSG_IN and STARTUP_CONFIGURATION_MSG_RECEIVED_INT) or
      (SESSION_CHECK_TURN_OFF_MSG_IN and TURN_OFF_MSG_RECEIVED_INT) ;
    end function;
begin
    process
        variable result:    boolean;
    begin
        wait for 10 ns;
        ASCERTAIN_CALL_VALIDITY(result);
        if not result then
            report "result is not TRUE";
        end if;
        if not call_validity then
            report "call_validity is FALSE";
        end if;
        wait;
    end process;
    
end architecture;