I want to copy and use the .SUBCKT model of UCC28C43 which is in an OrCAD capture schematic. I did as follows but the .subckt contains the undefinable text. why is that so? how can I find the correct .subckt? (except downloading from the manufacturer website)
1 Answer
If you relax the requirement to not download from the manufacturer site, you can visit page UCC28C43 data sheet, product information and support | TI.com, scroll to section Design & development
; at the section bottom, right of item UCCx8C43 Unencrypted PSpice Transient Model, click the Download
button.
The downloaded SLUM521.ZIP file contains file ucc28c43_trans_unencrypted.lib with unencrypted Pspice model for UCC28C43:
.SUBCKT UCC28C43_STEADY COMP FB CS RTCT GND OUT VDD VREF
****OSCILLATOR*****
STOF1 8 GND RTCT GND SOSC
GBDISCH RTCT GND Value = { IF ( V(8,GND) < 2.5 & V(13,GND) > 2.5, 8.4M, 0 ) }
RPULL 8 VREF 100K
****UVLO***********
STOF2 VDD 19 VDD GND SUVLO
RUVLO 19 GND 1MEG
RSTDBY VDD GND 309K ; startup current
ROP 10 GND 2535 ; operating current
****REFERENCE*******
EBREF 13 GND Value = { IF ( V(19,GND) > 6, 5, 0 ) }
RREG 10 VREF 0.158
CREF VREF GND 1N
V3 13 10
**GB6 19 GND Value = { IF ( V(19,GND) > 4 , (I(V3)) , 0 ) }
GB6 19 GND Value = { IF (V(19,GND) > 4 , IF((I(V3)-I(EMY19))>2,
+ 2, IF((I(V3)-I(EMY19))<0, 0,(I(V3)-I(EMY19)))), 0 ) }
****CURRENT COMPARATOR*******
EB3 21 GND Value = { IF ( V(CS,GND) > V(16,GND), 5, 0 ) }
R7 CS GND 1MEG
RDELAY 21 22 1K
CDELAY 22 GND 200P
****ERROR AMPLIFIER**********
XAMP VREF FB COMP GND 28C4xAMP
****OFFSET LIMITER***********
R4 12 11 2MEG
R6 11 GND 1MEG
EB2 16 GND Value = { IF ( V(11,GND) > 1, 1, V(11,GND) ) }
V4 COMP 9 1
D1 9 12 D2
****OUTPUT DRIVER************
EMY19 191 GND VALUE = {V(19,GND)}
XDRIVE 191 GND 5 OUT FETOUTC4X ; FETOUTC4X 2845OUT
****S-R LATCH****************
XLATCH 8 VREF 22 GND 6 7 FFLOPC2
****OUTPUT AND GATE**********
EOut 5 GND Value = { IF ( V(VREF,GND) > 2.5 & V(7,GND) >
+2.5 & V(8,GND) > 2.5, 5, 0 ) }
.MODEL SOSC VSWITCH (RON=.01 ROFF=1MEG VT=1.45 VH=0.95) ; VT=1.45 set to match 53k @ 3.3n/10k
.MODEL SUVLO VSWITCH (RON=.01 ROFF=10MEG VT=8.0 VH=0.4)
.MODEL D2 D
.ENDS UCC28C43_STEADY
both Transient Steady State and Startup versions can be found in this file.
-
1\$\begingroup\$ thanks, so the reason for what I've observed is the privacy policy and encryption and it's not remediable. right? (I ask if I encounter other cases in the future) \$\endgroup\$– WeTechSep 19, 2021 at 5:43
-
1\$\begingroup\$ @Kamran Yes, it's encrypted. So you are screwed unless you can find a tool to unencrypt what you have. And even then, you can't be sure. Sometimes, there are specialized models within a Spice program that are accessed by the unecrypted .SUBCKT model. These specialized models may not be present in some other Spice program. So there is no guarantee, even if you can unencrypt the model. \$\endgroup\$– jonkSep 19, 2021 at 5:46
-
\$\begingroup\$ The purpose of encryption is to enable distribution of the private document via open comm channels. In this case, the manufacturer provides both encrypted and unencrypted versions, and the resource does not require authorization (is accessible to general public, not only to the customers). You've chosen the encrypted version outside the license agreement required. The other possible reason of failure -- you need Pspice version 15.7 to work with encrypted models, and your tool's version is prior to the minimum required. \$\endgroup\$– V.V.TSep 19, 2021 at 6:00
-
\$\begingroup\$ But, fortunately for you, whatever reason for failure, the manufacturer offers the unencrypted version on par the encrypted one. \$\endgroup\$– V.V.TSep 19, 2021 at 6:01