0
\$\begingroup\$

I've installed PSpice for TI but I can't find NE5532 model on it? I'm searching for it's spice model to being able to simulate it on LTSPICE. (I wonder if TI does not included it's devices model in their Pspice, what this massive garbage application is included!)

\$\endgroup\$
2
  • \$\begingroup\$ I don't have PSpice but, if there isn't any such model in the default library (try searching only for 5532) then TI's page lists it as having a model, possibly with a request. \$\endgroup\$ Commented Jun 4, 2022 at 5:16
  • \$\begingroup\$ jeastham.blogspot.com/2011/11/… Adding a NE5532 Op Amp Model to LTSpice \$\endgroup\$ Commented Jun 4, 2022 at 5:18

2 Answers 2

3
\$\begingroup\$
To add the NE5532 Model, follow the steps in my LM741 post (see link below), using the NE5532 model shown here below.

Special thanks to Uwe Beis who provided the TI 5534 updated model:
(http://www.beis.de/Elektronik/Electronics.html)

Adding the LM741 model to LTSpice

***** NE5532 Source: Texas Instruments NE5534
* C2 added to simulate compensated frequency response (Uwe Beis)

* NE5532 OPERATIONAL AMPLIFIER "MACROMODEL" SUBCIRCUIT
* CREATED USING NE5534 model from Texas InstrumentsAT 12:41
* (REV N/A)      SUPPLY VOLTAGE: +/-15V
* CONNECTIONS:   NON-INVERTING INPUT
*                | INVERTING INPUT
*                | | POSITIVE POWER SUPPLY
*                | | | NEGATIVE POWER SUPPLY
*                | | | | OUTPUT
*                | | | | |
.SUBCKT NE5532   1 2 3 4 5
*
C1   11 12 7.703E-12
C2    6  7 23.500E-12
DC    5 53 DX
DE   54  5 DX
DLP  90 91 DX
DLN  92 90 DX
DP    4  3 DX
EGND 99  0 POLY(2) (3,0) (4,0) 0 .5 .5
FB    7 99 POLY(5) VB VC VE VLP VLN 0 2.893E6 -3E6 3E6 3E6 -3E6
GA    6  0 11 12 1.382E-3
GCM   0  6 10 99 13.82E-9
IEE  10  4 DC 133.0E-6
HLIM 90  0 VLIM 1K
Q1   11  2 13 QX
Q2   12  1 14 QX
R2    6  9 100.0E3
RC1   3 11 723.3
RC2   3 12 723.3
RE1  13 10 329
RE2  14 10 329
REE  10 99 1.504E6
RO1   8  5 50
RO2   7 99 25
RP    3  4 7.757E3
VB    9  0 DC 0
VC    3 53 DC 2.700
VE   54  4 DC 2.700
VLIM  7  8 DC 0
VLP  91  0 DC 38
VLN   0 92 DC 38
.MODEL DX D(IS=800.0E-18)
.MODEL QX NPN(IS=800.0E-18 BF=132)
.ENDS

http://jeastham.blogspot.com/2011/11/

\$\endgroup\$
3
  • \$\begingroup\$ This is not general opamp model then I hope it is more accurate. \$\endgroup\$ Commented Jun 11, 2022 at 5:12
  • \$\begingroup\$ How did it perform for you? \$\endgroup\$ Commented Jun 20, 2022 at 16:38
  • \$\begingroup\$ Thx. Performed well. I did not compare it with real experiment. but I've used it to just simulate before prototype. At least it is not catastrophically bad. :) \$\endgroup\$ Commented Jul 5, 2022 at 4:43
1
\$\begingroup\$

In micro-cap, the NE5532 model uses a standard op-amp with the parameters listed below. You can transfer the parameters to your equivalent standard op-amp: -

enter image description here

Or maybe you prefer it like this: -

.MODEL NE5532 OPA (LEVEL=3 A=100K GBW=10MEG IBIAS=200n IOFF=10n IOSC=38m
+ PD=100m ROUTAC=50 ROUTDC=75 SRN=9MEG SRP=9MEG VNS=-12.4 VOFF=500u VPS=12.4)
\$\endgroup\$
3
  • \$\begingroup\$ Thanks for application. Why your model and @Tony's model are not the same? which one is better? Maybe this is another question?! \$\endgroup\$ Commented Jun 6, 2022 at 15:56
  • \$\begingroup\$ And I wonder which one is best answer?! \$\endgroup\$ Commented Jun 6, 2022 at 16:02
  • \$\begingroup\$ You should choose not me!! \$\endgroup\$
    – Andy aka
    Commented Jun 6, 2022 at 16:10

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.