Electrical Engineering Stack Exchange is a question and answer site for electronics and electrical engineering professionals, students, and enthusiasts. It only takes a minute to sign up.
Sign up to join this community
I have imported a Spice model of an op-amp into OrCAD, but the part symbol is different from what I am used to, and I don't know what pins 4, 5, 8, and 11 represent here.
Link to spice model I used: https://www.eng.auburn.edu/~strouce/analogbc/opamp2.htm
Here is the symbol I am getting:
Edit: Found out what each pin represents. I made a voltage follower circuit, but no matter the input supply my output voltage is stuck at -13.53V
Voltage follower circuit I used:
The link you provide shows .subckt code which (mostly) matches the accompanying image of the opamp's internal schematic. I'll duplicate both for clarity and completeness below:
*operational ampplifier 2(Leap frog opamp)
.Subckt opamp 4 5 8 1 11
.MODEL mosn NMOS
+ vto=1 kp=17u gamma=1.3 lambda=0.01 phi=0.7
+pb=0.8 mj=0.5 mjsw=.3 cgso=350p cgdo=350p cgbo=200p
+cj=300u cjsw=500p ld=0.8u tox=80n
.MODEL mosp PMOS
+ vto=-1 kp=8u gamma=.6 lambda=0.02 phi=0.6
+pb=0.5 mj=0.5 mjsw=.25 cgso=350p cgdo=350p cgbo=200p
+cj=150u cjsw=400p ld=0.8u tox=80n
R1a 6 66 1
R1b 66 3 100meg
m1 66 4 3 3 mosp w=20u l=10u
R2a 7 77 1
R2b 77 3 100meg
m2 77 5 3 3 mosp w=20u l=10u
R3a 6 67 1
R3b 67 11 100meg
m3 67 6 11 11 mosn w=36u l=10u
R4a 7 78 1
R4b 78 11 100meg
m4 78 6 11 11 mosn w=36u l=10u
R5a 3 33 1
R5b 33 1 100meg
m5 33 2a 1 1 mosp w=30u l=10u
R6a 8 88 1
R6b 88 11 100meg
m6 88 7 11 11 mosn w=100u l=10u
R7a 8 89 1
R7b 89 1 100meg
m7 89 2 1 1 mosp w=42u l=10u
R8a 2 22 1
R8b 22 11 100meg
m8 22 6 11 11 mosn w=60u l=10u
R9a 2 23 1
R9b 23 1 100meg
m9 23 2 1 1 mosp w=30u l=10u
Rc 7 76 1
cc 76 8 6p
Rs 76 8 100meg
vbias 2a 0 .1
.ends
Our goal is to try and map the node numbers listed on the .subckt line to the actual pins labeled on the schematic image.
.subckt opamp 4 5 8 1 11
The first clue I see is there is only one capacitor, and one of its sides is connected to Vout in the image. I can easily find the capacitor in the .subckt code because it's the only line that starts with the letter "C":
cc 76 8 6p
Therefore, pin 8 is Vout.
Next, the image shows M7 as a PMOS transistor with its source connected to Vdd. MOSFET transistors in SPICE follow the following syntax and pin ordering:
Mxxx <drain> <gate> <source> <body> <modelname> [W=<width>] [L=<length>]
So for M7 we have:
m7 89 2 1 1 mosp w=42u l=10u
and therefore, pin 1 is Vdd.
We can do the same with NMOS transistor M6 and Vss:
m6 88 7 11 11 mosn w=100u l=10u
which means pin 11 is Vss.
The noninverting (+) input is connected to the gate of M2:
m2 77 5 3 3 mosp w=20u l=10u
So following the syntax definition above, pin 5 is the noninverting input.
Lastly, we do the same with the inverting (-) input and M1:
m1 66 4 3 3 mosp w=20u l=10u
which means pin 4 is the inverting input.
Summarizing, we have the following:
4 = inverting (-) input
5 = noninverting (+) input
8 = Vout
1 = Vdd
11 = Vss
Shown below is a DC operating point example of a "gain of 2" noninverting amplifier. One thing to note about this opamp model is that it only functions well enough in DC with high valued resistors. Reduce the gain/feedback resistors by a factor of 10 or 100 to see what I'm talking about.
The model you linked has this line: -
.Subckt opamp 4 5 8 1 11
And, if I look at similar op-amp models that I use, the pin order in my models are this: -
+Vin -Vin +Vsup -Vsup Output
So, it's a fair bet that if you connected up your model as an non-inverting voltage follower, you should get a response that looks like one. Do you know how to do this?
